Google Static Maps HTML Helper

CodeProject

One of the features that I like the most in ASP.NET MVC is HTML Helpers, I use them all the time, and I also use Google Maps very often, so it's natural to join them and create a simple HTML Helper Extension Method that you can use immediately in your applications.

Google Maps provides an API for generating map images from parametrized URLs called Google Static Maps API, so today we will create an Extension Method to the HtmlHelper class that you can use to easily embed a Google Static Map into any View Page.

We will start with some text from the API docs.

Google Static Maps API Query String Parameters

Create a new MVC 3 Web application and add the following module into your Models folder.

Google Static Map Extension Method (VB .NET)

Public Module HtmlHelpers

    <Runtime.CompilerServices.Extension()>
    Function GoogleStaticMap(helper As HtmlHelper,
                             title As String,
                             latitude As Decimal,
                             longitude As Decimal,
                             width As Integer, height As Integer,
                             Optional zoom As Integer = 15,
                             Optional language As String = "en") As MvcHtmlString

        'Google Static Map API - Base URL
        Dim googleApiUrl = "http://maps.googleapis.com/maps/api/staticmap?sensor=false"

        'a string builder for quicker text manipulation
        Dim url = New System.Text.StringBuilder

        'Setup URL with all required query strings

        'Base Url
        url.Insert(0, googleApiUrl)

        'Language
        url.Append("&language=")
        url.Append(language)

        'Zoom
        url.Append("&zoom=")
        url.Append(zoom.ToString)

        'Size
        url.Append("&size=")
        url.Append(width.ToString)
        url.Append("x")
        url.Append(height.ToString)

        'Markers "latitude,longitude"
        url.Append("&markers=")
        url.Append(latitude.ToString)
        url.Append(",")
        url.Append(longitude.ToString)

        'Create an <img src="URL" alr="title" />
        Dim imgTag = New TagBuilder("img")

        imgTag.MergeAttribute("src", url.ToString)
        imgTag.MergeAttribute("style", "border:1px solid black;")
        imgTag.MergeAttribute("alt", title)

        'Return the Encoded HTML
        Return MvcHtmlString.Create(imgTag.ToString(TagRenderMode.SelfClosing))

    End Function

End Module

Explain The Code

Using a string builder, we construct the final parameterized URL, notice that the markers parameter is of format “latitude,longitude”, then a TagBuilder is used to create our IMG tag with the attributes required to show a Google Static Map, as IMG tags are self-closing we select the self-closing TagRenderMode and return the final encoded HTML with MvcHtmlString.Create method.

That’s it, we create the URL, and then create an IMG tag with that URL as source.

How To Use It

In your Views/Home folder, open the Index.vbhtml page and use the following code:

@Code
    ViewData("Title") = "Index"
End Code

<h2>Google Static Maps - Example</h2>

@Html.GoogleStaticMap("My First Map", 12.250151, 64.33717, 550, 500)

Enhancements

• Geocoding feature
• Show multiple location markers
• Use map styles to change the appearance of the map
• Use marker styles to change the appearance of the marker

Summary

There are just too many features available in Google Maps API, we talked here about a quick and portable implementation that can quickly and easily fit into any project with a “Contact Us” page that needs a map. I hope that this can help you start your own Advanced Google Maps HTML Helper.