Visual Basic

TDDragon wrote:

I'v been reading alot about this and it seems it is no longer supported by microsoft in the .net2

' handle to finger image
Dim handle As IPictureDisp
frm.GrFingerXCtrl1.CapRawImageToHandle raw.img, raw.width, raw.height, frm.Hwnd, handle

    ' draw image on picture box
    If Not (handle Is Nothing) Then
        formMain.img.Picture = handle
    End If

TDDragon wrote:

due to lak of time I hade to put this 'project' in the freezer for a while so...

TDDragon wrote:

I'm unable to set it's property's, not in code and in design I can set them once just after I put the control on the form

Public Class Form1
    ' An array of textbox's
    Private ControlArray As New List(Of TextBox)

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        ' Here I am adding TextBox's that already exist on my form to the array
        With ControlArray
            .Add(TextBox1)
            .Add(TextBox2)
            .Add(TextBox3)
        End With

        ' Loop through each textbox in the array
        For Each tb As TextBox In ControlArray
            MsgBox(tb.Name)
        Next

        ' Access a textbox by index
        MsgBox(ControlArray(1).Name)

        ' Here I am creating textboxes dynamically and adding them
        ' to the array
        For i As Integer = 0 To 2
            ' Create a textbox
            Dim tb As New TextBox
            ' Set it's position
            tb.Location = New Point(20, 10 + i * 30)
            ' Set it's width
            tb.Width = 100

            ' Add the textbox to the array
            ControlArray.Add(tb)

            ' Add the textbox to the form
            Me.Controls.Add(tb)

            ' Add handlers for the GotFocus and LostFocus events
            AddHandler tb.GotFocus, AddressOf TextBox_GotFocus
            AddHandler tb.LostFocus, AddressOf TextBox_LostFocus
        Next

        ' Here I've looped through the forms controls and found
        ' all the textboxes and added them to the array
        ' This is a good approach if you have many controls you added at
        ' design time but don't want to manually add each one to the array.
        ' The desired event handlers can also be dynamically added this way
        For Each ctrl As Control In Me.Controls
            Dim tb As TextBox = TryCast(ctrl, TextBox)
            If tb IsNot Nothing Then
                ControlArray.Add(tb)
            End If
        Next
    End Sub

    ' Handles the textboxes GotFocus event
    ' I've handled the controls I created at design time by including them after the handles keyword
    Private Sub TextBox_GotFocus(ByVal sender As Object, ByVal e As System.EventArgs) Handles TextBox1.GotFocus, TextBox2.GotFocus, TextBox3.GotFocus
        ' tb is a reference to the textbox that raised this event
        Dim tb As TextBox = DirectCast(sender, TextBox)
        tb.BackColor = Color.Wheat
    End Sub

    ' Handles the textboxes LostFocus event
    ' I've handled the controls I created at design time by including them after the handles keyword
    Private Sub TextBox_LostFocus(ByVal sender As Object, ByVal e As System.EventArgs) Handles TextBox1.LostFocus, TextBox2.LostFocus, TextBox3.LostFocus
        ' tb is a reference to the textbox that raised this event
        Dim tb As TextBox = DirectCast(sender, TextBox)
        tb.BackColor = Color.White
    End Sub
End Class